Lisp Data Types
***************

A Lisp object is a piece of data used and manipulated by Lisp programs.  For our purposes, a type or data type is a set of possible objects.

Every object belongs to at least one type.  Objects of the same type have similar structures and may usually be used in the same contexts. Types can overlap, and objects can belong to two or more types. Consequently, we can ask whether an object belongs to a particular type, but not for ``the'' type of an object.

A few fundamental object types are built into XEmacs.  These, from which all other types are constructed, are called primitive types.  Each object belongs to one and only one primitive type.  These types include integer, float, cons, symbol, string, vector, subr, byte-code function, and several special types, such as buffer, that are related to editing.  (see Editing Types.)

Each primitive type has a corresponding Lisp function that checks whether an object is a member of that type.

Note that Lisp is unlike many other languages in that Lisp objects are self-typing: the primitive type of the object is implicit in the object itself.  For example, if an object is a vector, nothing can treat it as a number; Lisp knows it is a vector, not a number.

In most languages, the programmer must declare the data type of each variable, and the type is known by the compiler but not represented in the data.  Such type declarations do not exist in Emacs Lisp.  A Lisp variable can have any type of value, and it remembers whatever value you store in it, type and all.

This chapter describes the purpose, printed representation, and read syntax of each of the standard types in Emacs Lisp.  Details on how to use these types can be found in later chapters.

Printed Representation and Read Syntax
======================================

The printed representation of an object is the format of the output generated by the Lisp printer (the function prin1) for that object.  The read syntax of an object is the format of the input accepted by the Lisp reader (the function read) for that object.  Most objects have more than one possible read syntax.  Some types of object have no read syntax; except for these cases, the printed representation of an object is also a read syntax for it.

In other languages, an expression is text; it has no other form.  In Lisp, an expression is primarily a Lisp object and only secondarily the text that is the object's read syntax.  Often there is no need to emphasize this distinction, but you must keep it in the back of your mind, or you will occasionally be very confused.

Every type has a printed representation.  Some types have no read syntax, since it may not make sense to enter objects of these types directly in a Lisp program.  For example, the buffer type does not have a read syntax.  Objects of these types are printed in hash notation: the characters #< followed by a descriptive string (typically the type name followed by the name of the object), and closed with a matching >.  Hash notation cannot be read at all, so the Lisp reader signals the error invalid-read-syntax whenever it encounters #<.

     (current-buffer)
          => #<buffer objects.texi>

When you evaluate an expression interactively, the Lisp interpreter first reads the textual representation of it, producing a Lisp object, and then evaluates that object (see Evaluation).  However, evaluation and reading are separate activities.  Reading returns the Lisp object represented by the text that is read; the object may or may not be evaluated later.  See Input Functions, for a description of read, the basic function for reading objects.

Comments
========

A comment is text that is written in a program only for the sake of humans that read the program, and that has no effect on the meaning of the program.  In Lisp, a semicolon (;) starts a comment if it is not within a string or character constant.  The comment continues to the end of line.  The Lisp reader discards comments; they do not become part of the Lisp objects which represent the program within the Lisp system.

The #@COUNT construct, which skips the next COUNT characters, is useful for program-generated comments containing binary data.  The Emacs Lisp byte compiler uses this in its output files (see Byte Compilation).  It isn't meant for source files, however.

See Comment Tips, for conventions for formatting comments.

Programming Types
=================

There are two general categories of types in Emacs Lisp: those having to do with Lisp programming, and those having to do with editing.  The former exist in many Lisp implementations, in one form or another.  The latter are unique to Emacs Lisp.

Integer Type
------------

The range of values for integers in Emacs Lisp is -134217728 to 134217727 (28 bits; i.e., -2**27 to 2**27 - 1) on most machines.  (Some machines may provide a wider range.)  It is important to note that the Emacs Lisp arithmetic functions do not check for overflow.  Thus (1+ 134217727) is -134217728 on most machines.

The read syntax for integers is a sequence of (base ten) digits with an optional sign at the beginning and an optional period at the end.  The printed representation produced by the Lisp interpreter never has a leading + or a final ..

     -1               ; The integer -1.
     1                ; The integer 1.
     1.               ; Also The integer 1.
     +1               ; Also the integer 1.
     268435457        ; Also the integer 1!
                      ;   (on a 28-bit implementation)

See Numbers, for more information.

Floating Point Type
-------------------

XEmacs supports floating point numbers.  The precise range of floating point numbers is machine-specific.

The printed representation for floating point numbers requires either a decimal point (with at least one digit following), an exponent, or both.  For example, 1500.0, 15e2, 15.0e2, 1.5e3, and .15e4 are five ways of writing a floating point number whose value is 1500.  They are all equivalent.

See Numbers, for more information.

Character Type
--------------

A character in Emacs Lisp is nothing more than an integer.  In other words, characters are represented by their character codes.  For example, the character A is represented as the integer 65.

Individual characters are not often used in programs.  It is far more common to work with strings, which are sequences composed of characters.  See String Type.

Characters in strings, buffers, and files are currently limited to the range of 0 to 255---eight bits.  If you store a larger integer into a string, buffer or file, it is truncated to that range.  Characters that represent keyboard input have a much wider range.

Since characters are really integers, the printed representation of a character is a decimal number.  This is also a possible read syntax for a character, but writing characters that way in Lisp programs is a very bad idea.  You should always use the special read syntax formats that Emacs Lisp provides for characters.  These syntax formats start with a question mark.

The usual read syntax for alphanumeric characters is a question mark followed by the character; thus, ?A for the character A, ?B for the character B, and ?a for the character a.

For example:

     ?Q => 81     ?q => 113

You can use the same syntax for punctuation characters, but it is often a good idea to add a \ so that the Emacs commands for editing Lisp code don't get confused.  For example, ?\  is the way to write the space character.  If the character is \, you must use a second \ to quote it: ?\\.

You can express the characters Control-g, backspace, tab, newline, vertical tab, formfeed, return, and escape as ?\a, ?\b, ?\t, ?\n, ?\v, ?\f, ?\r, ?\e, respectively.  Those values are 7, 8, 9, 10, 11, 12, 13, and 27 in decimal.  Thus,

     ?\a => 7                 ; C-g
     ?\b => 8                 ; backspace, BS, C-h
     ?\t => 9                 ; tab, TAB, C-i
     ?\n => 10                ; newline, LFD, C-j
     ?\v => 11                ; vertical tab, C-k
     ?\f => 12                ; formfeed character, C-l
     ?\r => 13                ; carriage return, RET, C-m
     ?\e => 27                ; escape character, ESC, C-[
     ?\\ => 92                ; backslash character, \

These sequences which start with backslash are also known as escape sequences, because backslash plays the role of an escape character; this usage has nothing to do with the character ESC.

Control characters may be represented using yet another read syntax. This consists of a question mark followed by a backslash, caret, and the corresponding non-control character, in either upper or lower case.  For example, both ?\^I and ?\^i are valid read syntax for the character C-i, the character whose value is 9.

Instead of the ^, you can use C-; thus, ?\C-i is equivalent to ?\^I and to ?\^i:

     ?\^I => 9     ?\C-I => 9

For use in strings and buffers, you are limited to the control characters that exist in ASCII, but for keyboard input purposes, you can turn any character into a control character with C-.  The character codes for these non-ASCII control characters include the 2**26 bit as well as the code for the corresponding non-control character.  Ordinary terminals have no way of generating non-ASCII control characters, but you can generate them straightforwardly using an X terminal.

For historical reasons, Emacs treats the DEL character as the control equivalent of ?:

     ?\^? => 127     ?\C-? => 127

As a result, it is currently not possible to represent the character Control-?, which is a meaningful input character under X.  It is not easy to change this as various Lisp files refer to DEL in this way.

For representing control characters to be found in files or strings, we recommend the ^ syntax; for control characters in keyboard input, we prefer the C- syntax.  This does not affect the meaning of the program, but may guide the understanding of people who read it.

A meta character is a character typed with the META modifier key.  The integer that represents such a character has the 2**27 bit set (which on most machines makes it a negative number).  We use high bits for this and other modifiers to make possible a wide range of basic character codes.

In a string, the 2**7 bit indicates a meta character, so the meta characters that can fit in a string have codes in the range from 128 to 255, and are the meta versions of the ordinary ASCII characters. (In Emacs versions 18 and older, this convention was used for characters outside of strings as well.)

The read syntax for meta characters uses \M-.  For example, ?\M-A stands for M-A.  You can use \M- together with octal character codes (see below), with \C-, or with any other syntax for a character.  Thus, you can write M-A as ?\M-A, or as ?\M-\101.  Likewise, you can write C-M-b as ?\M-\C-b, ?\C-\M-b, or ?\M-\002.

The case of an ordinary letter is indicated by its character code as part of ASCII, but ASCII has no way to represent whether a control character is upper case or lower case.  Emacs uses the 2**25 bit to indicate that the shift key was used for typing a control character.  This distinction is possible only when you use X terminals or other special terminals; ordinary terminals do not indicate the distinction to the computer in any way.

The X Window System defines three other modifier bits that can be set in a character: hyper, super and alt.  The syntaxes for these bits are \H-, \s- and \A-.  Thus, ?\H-\M-\A-x represents Alt-Hyper-Meta-x. Numerically, the bit values are 2**22 for alt, 2**23 for super and 2**24 for hyper.

Finally, the most general read syntax consists of a question mark followed by a backslash and the character code in octal (up to three octal digits); thus, ?\101 for the character A, ?\001 for the character C-a, and ?\002 for the character C-b.  Although this syntax can represent any ASCII character, it is preferred only when the precise octal value is more important than the ASCII representation.

     ?\012 => 10         ?\n => 10         ?\C-j => 10
     ?\101 => 65         ?A => 65

A backslash is allowed, and harmless, preceding any character without a special escape meaning; thus, ?\+ is equivalent to ?+. There is no reason to add a backslash before most characters.  However, you should add a backslash before any of the characters ()\|;'`"#., to avoid confusing the Emacs commands for editing Lisp code.  Also add a backslash before whitespace characters such as space, tab, newline and formfeed.  However, it is cleaner to use one of the easily readable escape sequences, such as \t, instead of an actual whitespace character such as a tab.

Symbol Type
-----------

A symbol in GNU Emacs Lisp is an object with a name.  The symbol name serves as the printed representation of the symbol.  In ordinary use, the name is unique---no two symbols have the same name.

A symbol can serve as a variable, as a function name, or to hold a property list.  Or it may serve only to be distinct from all other Lisp objects, so that its presence in a data structure may be recognized reliably.  In a given context, usually only one of these uses is intended.  But you can use one symbol in all of these ways, independently.

A symbol name can contain any characters whatever.  Most symbol names are written with letters, digits, and the punctuation characters -+=*/.  Such names require no special punctuation; the characters of the name suffice as long as the name does not look like a number. (If it does, write a \ at the beginning of the name to force interpretation as a symbol.)  The characters _~!@$%^&:<>{} are less often used but also require no special punctuation.  Any other characters may be included in a symbol's name by escaping them with a backslash.  In contrast to its use in strings, however, a backslash in the name of a symbol simply quotes the single character that follows the backslash.  For example, in a string, \t represents a tab character; in the name of a symbol, however, \t merely quotes the letter t.  To have a symbol with a tab character in its name, you must actually use a tab (preceded with a backslash).  But it's rare to do such a thing.

     Common Lisp note: In Common Lisp, lower case letters are always ``folded'' to upper case, unless they are explicitly escaped.  In Emacs Lisp, upper case and lower case letters are distinct.

Here are several examples of symbol names.  Note that the + in the fifth example is escaped to prevent it from being read as a number. This is not necessary in the sixth example because the rest of the name makes it invalid as a number.

     foo                 ; A symbol named foo.
     FOO                 ; A symbol named FOO, different from foo.
     char-to-string      ; A symbol named char-to-string.

     1+                  ; A symbol named 1+
                         ;   (not +1, which is an integer).

     \+1                 ; A symbol named +1
                         ;   (not a very readable name).

     \(*\ 1\ 2\)         ; A symbol named (* 1 2) (a worse name).
     +-*/_~!@$%^&=:<>{}  ; A symbol named +-*/_~!@$%^&=:<>{}.
                         ;   These characters need not be escaped.

Sequence Types
--------------

A sequence is a Lisp object that represents an ordered set of elements.  There are two kinds of sequence in Emacs Lisp, lists and arrays.  Thus, an object of type list or of type array is also considered a sequence.

Arrays are further subdivided into strings and vectors.  Vectors can hold elements of any type, but string elements must be characters in the range from 0 to 255.  However, the characters in a string can have text properties like characters in a buffer (see Text Properties); vectors do not support text properties even when their elements happen to be characters.

Lists, strings and vectors are different, but they have important similarities.  For example, all have a length L, and all have elements which can be indexed from zero to L minus one.  Also, several functions, called sequence functions, accept any kind of sequence.  For example, the function elt can be used to extract an element of a sequence, given its index.  See Sequences Arrays Vectors.

It is impossible to read the same sequence twice, since sequences are always created anew upon reading.  If you read the read syntax for a sequence twice, you get two sequences with equal contents.  There is one exception: the empty list () always stands for the same object, nil.

Cons Cell and List Types
------------------------

A cons cell is an object comprising two pointers named the CAR and the CDR.  Each of them can point to any Lisp object.

A list is a series of cons cells, linked together so that the CDR of each cons cell points either to another cons cell or to the empty list.  See Lists, for functions that work on lists.  Because most cons cells are used as part of lists, the phrase list structure has come to refer to any structure made out of cons cells.

The names CAR and CDR have only historical meaning now.  The original Lisp implementation ran on an IBM 704 computer which divided words into two parts, called the ``address'' part and the ``decrement''; CAR was an instruction to extract the contents of the address part of a register, and CDR an instruction to extract the contents of the decrement.  By contrast, ``cons cells'' are named for the function cons that creates them, which in turn is named for its purpose, the construction of cells.

Because cons cells are so central to Lisp, we also have a word for ``an object which is not a cons cell''.  These objects are called atoms.

The read syntax and printed representation for lists are identical, and consist of a left parenthesis, an arbitrary number of elements, and a right parenthesis.

Upon reading, each object inside the parentheses becomes an element of the list.  That is, a cons cell is made for each element.  The CAR of the cons cell points to the element, and its CDR points to the next cons cell of the list, which holds the next element in the list.  The CDR of the last cons cell is set to point to nil.

A list can be illustrated by a diagram in which the cons cells are shown as pairs of boxes.  (The Lisp reader cannot read such an illustration; unlike the textual notation, which can be understood by both humans and computers, the box illustrations can be understood only by humans.)  The following represents the three-element list (rose violet buttercup):

         ___ ___      ___ ___      ___ ___
        |___|___|--> |___|___|--> |___|___|--> nil
          |            |            |
          |            |            |
           --> rose     --> violet   --> buttercup

In this diagram, each box represents a slot that can refer to any Lisp object.  Each pair of boxes represents a cons cell.  Each arrow is a reference to a Lisp object, either an atom or another cons cell.

In this example, the first box, the CAR of the first cons cell, refers to or ``contains'' rose (a symbol).  The second box, the CDR of the first cons cell, refers to the next pair of boxes, the second cons cell.  The CAR of the second cons cell refers to violet and the CDR refers to the third cons cell.  The CDR of the third (and last) cons cell refers to nil.

Here is another diagram of the same list, (rose violet buttercup), sketched in a different manner:

      ---------------       ----------------       -------------------
     | car   | cdr   |     | car    | cdr   |     | car       | cdr   |
     | rose  |   o-------->| violet |   o-------->| buttercup |  nil  |
     |       |       |     |        |       |     |           |       |
      ---------------       ----------------       -------------------

A list with no elements in it is the empty list; it is identical to the symbol nil.  In other words, nil is both a symbol and a list.

Here are examples of lists written in Lisp syntax:

     (A 2 "A")            ; A list of three elements.
     ()                   ; A list of no elements (the empty list).
     nil                  ; A list of no elements (the empty list).
     ("A ()")             ; A list of one element: the string "A ()".
     (A ())               ; A list of two elements: A and the empty list.
     (A nil)              ; Equivalent to the previous.
     ((A B C))            ; A list of one element
                          ;   (which is a list of three elements).

Here is the list (A ()), or equivalently (A nil), depicted with boxes and arrows:

         ___ ___      ___ ___
        |___|___|--> |___|___|--> nil
          |            |
          |            |
           --> A        --> nil

Dotted Pair Notation
....................

Dotted pair notation is an alternative syntax for cons cells that represents the CAR and CDR explicitly.  In this syntax, (A . B) stands for a cons cell whose CAR is the object A, and whose CDR is the object B.  Dotted pair notation is therefore more general than list syntax.  In the dotted pair notation, the list (1 2 3) is written as (1 .  (2 . (3 . nil))).  For nil-terminated lists, the two notations produce the same result, but list notation is usually clearer and more convenient when it is applicable.  When printing a list, the dotted pair notation is only used if the CDR of a cell is not a list.

Here's how box notation can illustrate dotted pairs.  This example shows the pair (rose . violet):

         ___ ___
        |___|___|--> violet
          |
          |
           --> rose

Dotted pair notation can be combined with list notation to represent a chain of cons cells with a non-nil final CDR.  For example, (rose violet . buttercup) is equivalent to (rose . (violet . buttercup)).  The object looks like this:

         ___ ___      ___ ___
        |___|___|--> |___|___|--> buttercup
          |            |
          |            |
           --> rose     --> violet

These diagrams make it evident why (rose . violet . buttercup) is invalid syntax; it would require a cons cell that has three parts rather than two.

The list (rose violet) is equivalent to (rose . (violet)) and looks like this:

         ___ ___      ___ ___
        |___|___|--> |___|___|--> nil
          |            |
          |            |
           --> rose     --> violet

Similarly, the three-element list (rose violet buttercup) is equivalent to (rose . (violet . (buttercup))). It looks like this:

         ___ ___      ___ ___      ___ ___
        |___|___|--> |___|___|--> |___|___|--> nil
          |            |            |
          |            |            |
           --> rose     --> violet   --> buttercup

Association List Type
.....................

An association list or alist is a specially-constructed list whose elements are cons cells.  In each element, the CAR is considered a key, and the CDR is considered an associated value.  (In some cases, the associated value is stored in the CAR of the CDR.)  Association lists are often used as stacks, since it is easy to add or remove associations at the front of the list.

For example,

     (setq alist-of-colors
           '((rose . red) (lily . white)  (buttercup . yellow)))

sets the variable alist-of-colors to an alist of three elements.  In the first element, rose is the key and red is the value.

See Association Lists, for a further explanation of alists and for functions that work on alists.

Array Type
----------

An array is composed of an arbitrary number of slots for referring to other Lisp objects, arranged in a contiguous block of memory.  Accessing any element of an array takes the same amount of time.  In contrast, accessing an element of a list requires time proportional to the position of the element in the list.  (Elements at the end of a list take longer to access than elements at the beginning of a list.)

XEmacs defines two types of array, strings and vectors.  A string is an array of characters and a vector is an array of arbitrary objects.  Both are one-dimensional.  (Most other programming languages support multidimensional arrays, but they are not essential; you can get the same effect with an array of arrays.)  Each type of array has its own read syntax; see String Type, and Vector Type.

An array may have any length up to the largest integer; but once created, it has a fixed size.  The first element of an array has index zero, the second element has index 1, and so on.  This is called zero-origin indexing.  For example, an array of four elements has indices 0, 1, 2, and 3.

The array type is contained in the sequence type and contains both the string type and the vector type.

String Type
-----------

A string is an array of characters.  Strings are used for many purposes in XEmacs, as can be expected in a text editor; for example, as the names of Lisp symbols, as messages for the user, and to represent text extracted from buffers.  Strings in Lisp are constants: evaluation of a string returns the same string.

The read syntax for strings is a double-quote, an arbitrary number of characters, and another double-quote, "like this".  The Lisp reader accepts the same formats for reading the characters of a string as it does for reading single characters (without the question mark that begins a character literal).  You can enter a nonprinting character such as tab, C-a or M-C-A using the convenient escape sequences, like this: "\t, \C-a, \M-\C-a".  You can include a double-quote in a string by preceding it with a backslash; thus, "\"" is a string containing just a single double-quote character. (see Character Type, for a description of the read syntax for characters.)

If you use the \M- syntax to indicate a meta character in a string constant, this sets the 2**7 bit of the character in the string. This is not the same representation that the meta modifier has in a character on its own (not inside a string).  See Character Type.

Strings cannot hold characters that have the hyper, super, or alt modifiers; they can hold ASCII control characters, but no others. They do not distinguish case in ASCII control characters.

The printed representation of a string consists of a double-quote, the characters it contains, and another double-quote.  However, you must escape any backslash or double-quote characters in the string with a backslash, like this: "this \" is an embedded quote".

The newline character is not special in the read syntax for strings; if you write a new line between the double-quotes, it becomes a character in the string.  But an escaped newline---one that is preceded by \---does not become part of the string; i.e., the Lisp reader ignores an escaped newline while reading a string.

     "It is useful to include newlines
     in documentation strings,
     but the newline is \
     ignored if escaped."
          => "It is useful to include newlines
     in documentation strings,
     but the newline is ignored if escaped."

A string can hold properties of the text it contains, in addition to the characters themselves.  This enables programs that copy text between strings and buffers to preserve the properties with no special effort. See Text Properties.  Strings with text properties have a special read and print syntax:

     #("CHARACTERS" PROPERTY-DATA...)

where PROPERTY-DATA consists of zero or more elements, in groups of three as follows:

     BEG END PLIST

The elements BEG and END are integers, and together specify a range of indices in the string; PLIST is the property list for that range.

See Strings and Characters, for functions that work on strings.

Vector Type
-----------

A vector is a one-dimensional array of elements of any type.  It takes a constant amount of time to access any element of a vector.  (In a list, the access time of an element is proportional to the distance of the element from the beginning of the list.)

The printed representation of a vector consists of a left square bracket, the elements, and a right square bracket.  This is also the read syntax.  Like numbers and strings, vectors are considered constants for evaluation.

     [1 "two" (three)]      ; A vector of three elements.
          => [1 "two" (three)]

See Vectors, for functions that work with vectors.

Function Type
-------------

Just as functions in other programming languages are executable, Lisp function objects are pieces of executable code.  However, functions in Lisp are primarily Lisp objects, and only secondarily the text which represents them.  These Lisp objects are lambda expressions: lists whose first element is the symbol lambda (see Lambda Expressions).

In most programming languages, it is impossible to have a function without a name.  In Lisp, a function has no intrinsic name.  A lambda expression is also called an anonymous function (see Anonymous Functions).  A named function in Lisp is actually a symbol with a valid function in its function cell (see Defining Functions).

Most of the time, functions are called when their names are written in Lisp expressions in Lisp programs.  However, you can construct or obtain a function object at run time and then call it with the primitive functions funcall and apply.  See Calling Functions.

Macro Type
----------

A Lisp macro is a user-defined construct that extends the Lisp language.  It is represented as an object much like a function, but with different parameter-passing semantics.  A Lisp macro has the form of a list whose first element is the symbol macro and whose CDR is a Lisp function object, including the lambda symbol.

Lisp macro objects are usually defined with the built-in defmacro function, but any list that begins with macro is a macro as far as XEmacs is concerned.  See Macros, for an explanation of how to write a macro.

Primitive Function Type
-----------------------

A primitive function is a function callable from Lisp but written in the C programming language.  Primitive functions are also called subrs or built-in functions.  (The word ``subr'' is derived from ``subroutine''.)  Most primitive functions evaluate all their arguments when they are called.  A primitive function that does not evaluate all its arguments is called a special form (see Special Forms).

It does not matter to the caller of a function whether the function is primitive.  However, this does matter if you try to substitute a function written in Lisp for a primitive of the same name.  The reason is that the primitive function may be called directly from C code. Calls to the redefined function from Lisp will use the new definition, but calls from C code may still use the built-in definition.

The term function refers to all Emacs functions, whether written in Lisp or C.  See Function Type, for information about the functions written in Lisp.

Primitive functions have no read syntax and print in hash notation with the name of the subroutine.

     (symbol-function 'car)          ; Access the function cell
                                     ;   of the symbol.
          => #<subr car>
     (subrp (symbol-function 'car))  ; Is this a primitive function?
          => t                       ; Yes.

Byte-Code Function Type
-----------------------

The byte compiler produces byte-code function objects. Internally, a byte-code function object is much like a vector; however, the evaluator handles this data type specially when it appears as a function to be called.  See Byte Compilation, for information about the byte compiler.

The printed representation and read syntax for a byte-code function object is like that for a vector, with an additional # before the opening [.

Autoload Type
-------------

An autoload object is a list whose first element is the symbol autoload.  It is stored as the function definition of a symbol as a placeholder for the real definition; it says that the real definition is found in a file of Lisp code that should be loaded when necessary. The autoload object contains the name of the file, plus some other information about the real definition.

After the file has been loaded, the symbol should have a new function definition that is not an autoload object.  The new definition is then called as if it had been there to begin with.  From the user's point of view, the function call works as expected, using the function definition in the loaded file.

An autoload object is usually created with the function autoload, which stores the object in the function cell of a symbol.  See Autoload, for more details.

Editing Types
=============

The types in the previous section are common to many Lisp dialects. Emacs Lisp provides several additional data types for purposes connected with editing.

Buffer Type
-----------

A buffer is an object that holds text that can be edited (see Buffers).  Most buffers hold the contents of a disk file (see Files) so they can be edited, but some are used for other purposes.  Most buffers are also meant to be seen by the user, and therefore displayed, at some time, in a window (see Windows).  But a buffer need not be displayed in any window.

The contents of a buffer are much like a string, but buffers are not used like strings in Emacs Lisp, and the available operations are different.  For example, insertion of text into a buffer is very efficient, whereas ``inserting'' text into a string requires concatenating substrings, and the result is an entirely new string object.

Each buffer has a designated position called point (see Positions).  At any time, one buffer is the current buffer.  Most editing commands act on the contents of the current buffer in the neighborhood of point.  Many of the standard Emacs functions manipulate or test the characters in the current buffer; a whole chapter in this manual is devoted to describing these functions (see Text).

Several other data structures are associated with each buffer:

  * a local syntax table (see Syntax Tables);

  * a local keymap (see Keymaps); and,

  * a local variable binding list (see Buffer-Local Variables).

  * a list of extents (see Extents).

The local keymap and variable list contain entries that individually override global bindings or values.  These are used to customize the behavior of programs in different buffers, without actually changing the programs.

A buffer may be indirect, which means it shares the text of another buffer.  See Indirect Buffers.

Buffers have no read syntax.  They print in hash notation, showing the buffer name.

     (current-buffer)
          => #<buffer objects.texi>

Marker Type
-----------

A marker denotes a position in a specific buffer.  Markers therefore have two components: one for the buffer, and one for the position.  Changes in the buffer's text automatically relocate the position value as necessary to ensure that the marker always points between the same two characters in the buffer.

Markers have no read syntax.  They print in hash notation, giving the current character position and the name of the buffer.

     (point-marker)
          => #<marker at 10779 in objects.texi>

See Markers, for information on how to test, create, copy, and move markers.

Window Type
-----------

A window describes the portion of the terminal frame that XEmacs uses to display a buffer.  Every window has one associated buffer, whose contents appear in the window.  By contrast, a given buffer may appear in one window, no window, or several windows.

Though many windows may exist simultaneously, at any time one window is designated the selected window.  This is the window where the cursor is (usually) displayed when Emacs is ready for a command.  The selected window usually displays the current buffer, but this is not necessarily the case.

Windows are grouped on the screen into frames; each window belongs to one and only one frame.  See Frame Type.

Windows have no read syntax.  They print in hash notation, giving the window number and the name of the buffer being displayed.  The window numbers exist to identify windows uniquely, since the buffer displayed in any given window can change frequently.

     (selected-window)
          => #<window 1 on objects.texi>

See Windows, for a description of the functions that work on windows.

Frame Type
----------

A FRAME is a rectangle on the screen that contains one or more Emacs windows.  A frame initially contains a single main window (plus perhaps a minibuffer window) which you can subdivide vertically or horizontally into smaller windows.

Frames have no read syntax.  They print in hash notation, giving the frame's title, plus its address in core (useful to identify the frame uniquely).

     (selected-frame)
          => #<frame xemacs@mole.gnu.ai.mit.edu 0xdac80>

See Frames, for a description of the functions that work on frames.

Window Configuration Type
-------------------------

A window configuration stores information about the positions, sizes, and contents of the windows in a frame, so you can recreate the same arrangement of windows later.

Window configurations do not have a read syntax.  They print as #<window-configuration>.  See Window Configurations, for a description of several functions related to window configurations.

Process Type
------------

The word process usually means a running program.  Emacs itself runs in a process of this sort.  However, in Emacs Lisp, a process is a Lisp object that designates a subprocess created by the Emacs process. Programs such as shells, GDB, ftp, and compilers, running in subprocesses of Emacs, extend the capabilities of Emacs.

An Emacs subprocess takes textual input from Emacs and returns textual output to Emacs for further manipulation.  Emacs can also send signals to the subprocess.

Process objects have no read syntax.  They print in hash notation, giving the name of the process:

     (process-list)
          => (#<process shell>)

See Processes, for information about functions that create, delete, return information about, send input or signals to, and receive output from processes.

Stream Type
-----------

A stream is an object that can be used as a source or sink for characters---either to supply characters for input or to accept them as output.  Many different types can be used this way: markers, buffers, strings, and functions.  Most often, input streams (character sources) obtain characters from the keyboard, a buffer, or a file, and output streams (character sinks) send characters to a buffer, such as a *Help* buffer, or to the echo area.

The object nil, in addition to its other meanings, may be used as a stream.  It stands for the value of the variable standard-input or standard-output.  Also, the object t as a stream specifies input using the minibuffer (see Minibuffers) or output in the echo area (see The Echo Area).

Streams have no special printed representation or read syntax, and print as whatever primitive type they are.

See Read and Print, for a description of functions related to streams, including parsing and printing functions.

Keymap Type
-----------

A keymap maps keys typed by the user to commands.  This mapping controls how the user's command input is executed.  A keymap is actually a list whose CAR is the symbol keymap.

See Keymaps, for information about creating keymaps, handling prefix keys, local as well as global keymaps, and changing key bindings.

Syntax Table Type
-----------------

A syntax table is a vector of 256 integers.  Each element of the vector defines how one character is interpreted when it appears in a buffer.  For example, in C mode (see Major Modes), the + character is punctuation, but in Lisp mode it is a valid character in a symbol.  These modes specify different interpretations by changing the syntax table entry for +, at index 43 in the syntax table.

Syntax tables are used only for scanning text in buffers, not for reading Lisp expressions.  The table the Lisp interpreter uses to read expressions is built into the XEmacs source code and cannot be changed; thus, to change the list delimiters to be { and } instead of ( and ) would be impossible.

See Syntax Tables, for details about syntax classes and how to make and modify syntax tables.

Display Table Type
------------------

A display table specifies how to display each character code. Each buffer and each window can have its own display table.  A display table is actually a vector of length 262.  See Display Tables.

Extent Type
-----------

An extent specifies temporary alteration of the display appearance of a part of a buffer.  It contains markers delimiting a range of the buffer, plus a property list (a list whose elements are alternating property names and values).  Extents are used to present parts of the buffer temporarily in a different display style.  They have no read syntax, and print in hash notation, giving the buffer name and range of positions.

See Extents, for how to create and use extents.

Window-System Types
===================

XEmacs also has some types that represent objects such as fonts and bitmaps that are commonly found in windowing systems.

Font Type
---------

Color Type
----------

Pixmap Type
-----------

Type Predicates
===============

The Emacs Lisp interpreter itself does not perform type checking on the actual arguments passed to functions when they are called.  It could not do so, since function arguments in Lisp do not have declared data types, as they do in other programming languages.  It is therefore up to the individual function to test whether each actual argument belongs to a type that the function can use.

All built-in functions do check the types of their actual arguments when appropriate, and signal a wrong-type-argument error if an argument is of the wrong type.  For example, here is what happens if you pass an argument to + that it cannot handle:

     (+ 2 'a)
          error--> Wrong type argument: integer-or-marker-p, a

If you want your program to handle different types differently, you must do explicit type checking.  The most common way to check the type of an object is to call a type predicate function.  Emacs has a type predicate for each type, as well as some predicates for combinations of types.

A type predicate function takes one argument; it returns t if the argument belongs to the appropriate type, and nil otherwise. Following a general Lisp convention for predicate functions, most type predicates' names end with p.

Here is an example which uses the predicates listp to check for a list and symbolp to check for a symbol.

     (defun add-on (x)
       (cond ((symbolp x)
              ;; If X is a symbol, put it on LIST.
              (setq list (cons x list)))
             ((listp x)
              ;; If X is a list, add its elements to LIST.
              (setq list (append x list)))
             (t
              ;; We only handle symbols and lists.
              (error "Invalid argument %s in add-on" x))))

Here is a table of predefined type predicates, in alphabetical order, with references to further information.

arrayp
     See arrayp.

atom
     See atom.

boolean-specifier-p
     See boolean-specifier-p.

buffer-live-p
     See buffer-live-p.

bufferp
     See bufferp.

button-event-p
     See button-event-p.

button-press-event-p
     See button-press-event-p.

button-release-event-p
     See button-release-event-p.

case-table-p
     See case-table-p.

char-or-string-p
     See char-or-string-p.

color-instance-p
     See color-instance-p.

color-specifier-p
     See color-specifier-p.

commandp
     See commandp.

compiled-function-p
     See compiled-function-p.

consp
     See consp.

cursorp
     (not yet documented)

device-live-p
     See device-live-p.

device-or-frame-p
     See device-or-frame-p.

devicep
     See devicep.

eval-event-p
     See eval-event-p.

event-live-p
     See event-live-p.

eventp
     See eventp.

extent-live-p
     See extent-live-p.

extentp
     See extentp.

extent-replica-live-p
     See extent-replica-live-p.

extent-replica-p
     See extent-replica-p.

facep
     See facep.

floatp
     See floatp.

font-instance-p
     See font-instance-p.

font-specifier-p
     See font-specifier-p.

frame-live-p
     See frame-live-p.

framep
     See framep.

generic-specifier-p
     See generic-specifier-p.

glyphp
     See glyphp.

hashtablep
     (not yet documented)

image-instance-p
     See image-instance-p.

image-specifier-p
     See image-specifier-p.

integer-or-marker-p
     See integer-or-marker-p.

integer-specifier-p
     See integer-specifier-p.

integerp
     See integerp.

itimerp
     (not yet documented).

key-press-event-p
     See key-press-event-p.

keymapp
     See keymapp.

keywordp
     (not yet documented)

listp
     See listp.

markerp
     See markerp.

misc-user-event-p
     See misc-user-event-p.

motion-event-p
     See motion-event-p.

natnum-specifier-p
     See natnum-specifier-p.

natnump
     See natnump.

nlistp
     See nlistp.

numberp
     See numberp.

number-or-marker-p
     See number-or-marker-p.

process-event-p
     See process-event-p.

processp
     See processp.

ringp
     (not yet documented)

sequencep
     See sequencep.

specifierp
     See specifierp.

streamp
     (not yet documented)

stringp
     See stringp.

subrp
     See subrp.

subwindowp
     (not yet documented)

symbolp
     See symbolp.

syntax-table-p
     See syntax-table-p.

timeout-event-p
     See timeout-event-p.

toolbar-button-p
     See toolbar-button-p.

toolbar-specifier-p
     See toolbar-specifier-p.

user-variable-p
     See user-variable-p.

vectorp
     See vectorp.

wholenump
     See wholenump.

window-configuration-p
     See window-configuration-p.

window-live-p
     See window-live-p.

windowp
     See windowp.

The most general way to check the type of an object is to call the function type-of.  Recall that each object belongs to one and only one primitive type; type-of tells you which one (see Lisp Data Types).  But type-of knows nothing about non-primitive types.  In most cases, it is more convenient to use type predicates than type-of.

 -- Function: type-of object
     This function returns a symbol naming the primitive type of OBJECT.  The value is one of symbol, integer, float, string, cons, vector, marker, overlay, window, buffer, subr, compiled-function, window-configuration, or process.

          (type-of 1)
               => integer
          (type-of 'nil)
               => symbol
          (type-of '())    ; () is nil.
               => symbol
          (type-of '(x))
               => cons

Equality Predicates
===================

Here we describe two functions that test for equality between any two objects.  Other functions test equality between objects of specific types, e.g., strings.  For these predicates, see the appropriate chapter describing the data type.

 -- Function: eq object1 object2
     This function returns t if OBJECT1 and OBJECT2 are the same object, nil otherwise.  The ``same object'' means that a change in one will be reflected by the same change in the other.

     eq returns t if OBJECT1 and OBJECT2 are integers with the same value.  Also, since symbol names are normally unique, if the arguments are symbols with the same name, they are eq.  For other types (e.g., lists, vectors, strings), two arguments with the same contents or elements are not necessarily eq to each other: they are eq only if they are the same object.

     (The make-symbol function returns an uninterned symbol that is not interned in the standard obarray.  When uninterned symbols are in use, symbol names are no longer unique.  Distinct symbols with the same name are not eq.  See Creating Symbols.)

          (eq 'foo 'foo)
               => t

          (eq 456 456)
               => t

          (eq "asdf" "asdf")
               => nil

          (eq '(1 (2 (3))) '(1 (2 (3))))
               => nil

          (setq foo '(1 (2 (3))))
               => (1 (2 (3)))
          (eq foo foo)
               => t
          (eq foo '(1 (2 (3))))
               => nil

          (eq [(1 2) 3] [(1 2) 3])
               => nil

          (eq (point-marker) (point-marker))
               => nil

 -- Function: equal object1 object2
     This function returns t if OBJECT1 and OBJECT2 have equal components, nil otherwise.  Whereas eq tests if its arguments are the same object, equal looks inside nonidentical arguments to see if their elements are the same.  So, if two objects are eq, they are equal, but the converse is not always true.

          (equal 'foo 'foo)
               => t

          (equal 456 456)
               => t

          (equal "asdf" "asdf")
               => t

          (eq "asdf" "asdf")
               => nil

          (equal '(1 (2 (3))) '(1 (2 (3))))
               => t

          (eq '(1 (2 (3))) '(1 (2 (3))))
               => nil

          (equal [(1 2) 3] [(1 2) 3])
               => t

          (eq [(1 2) 3] [(1 2) 3])
               => nil

          (equal (point-marker) (point-marker))
               => t

          (eq (point-marker) (point-marker))
               => nil

     Comparison of strings is case-sensitive and takes account of text properties as well as the characters in the strings.  To compare two strings' characters without comparing their text properties, use string= (see Text Comparison).

          (equal "asdf" "ASDF")
               => nil

     Two distinct buffers are never equal, even if their contents are the same.

The test for equality is implemented recursively, and circular lists may therefore cause infinite recursion (leading to an error).